Arrays

También conocido con las denominaciones de matriz y vector, un array es aquel elemento del lenguaje que nos permite agrupar un conjunto de valores del mismo tipo, y acceder a ellos a través de una misma variable o identificador, especificando la posición o índice en donde se encuentra el dato a recuperar.

ejemplo:

Sub Main()


' declarar un array de tipo String,

' el número de elementos es el indicado

' en la declaración más uno, porque la primera

' posición de un array es cero

Dim sNombres(3) As String

' asignar valores al array

sNombres(0) = "Ana"

sNombres(1) = "Pedro"

sNombres(2) = "Antonio"

sNombres(3) = "Laura"

' pasar un valor del array a una variable

Dim sValor As String

sValor = sNombres(2)

' mostrar en la consola el valor pasado a una variable

' y un valor directamente desde el array

Console.WriteLine("Valor de la variable sValor: {0}", sValor)


Console.WriteLine("Valor del array, posición 1: {0}", sNombres(1))

Console.ReadLine()

End Sub
 
 
Declaración

Declararemos un array de igual forma que hacemos con una variable normal, con la excepción de que junto al nombre de la variable, situaremos unos paréntesis. Esto indica que dicha variable contiene un array. Opcionalmente, podemos especificar entre los paréntesis las dimensiones del array, o número de elementos que va a contener. Es posible también, realizar una asignación de valores al array en el mismo momento de su declaración.

ejemplo:

Sub Main()

' formas de declaración de arrays

' ===============================

' 1)

' estableciendo el número de elementos

Dim sNombres(2) As String

' 2)

' asignando valores al array al mismo tiempo que se declara,

' la lista de valores debe ir encerrada entre llaves

Dim sEstaciones() As String = {"Ana", "Pedro", "Luis"}

' 3)

' indicando el tipo de dato pero no el número de elementos,

' de este modo la variable todavía no es considerada un array

' ya que contiene una referencia a Nothing

Dim iValores() As Integer

' 4)

' indicando el tipo de dato y estableciendo una

' lista vacía de elementos,

' a diferencia del caso anterior, la variable ahora sí

' es considerada un array aunque de longitud cero

Dim iDatos() As Integer = {}

' 5)

' instanciando el tipo de dato, estableciendo el número

' de elementos al instanciar, e indicando que se trata de un array

' al situar las llaves

Dim iCantidades() As Integer = New Integer(20) {}

' 6)

' declarar primero la variable que contendrá el array,

' asignar valores al array al mismo tiempo que se instancia

' la lista de valores debe ir encerrada entre llaves

Dim iNumeros() As Integer

iNumeros = New Integer() {10, 20, 30, 10, 50, 60, 10, 70, 80}

End Sub
 
 
 
Uso del método CreateInstance( ) para establecer el número de elementos en un array
 

Ya hemos comprobado que al crear un array en VB.NET, el primer índice es siempre cero, y además, el número de elementos del array es el indicado en la declaración más uno.

Sin embargo, la clase Array dispone del método compartido CreateInstance( ), que como su nombre indica, permite crear una nueva instancia de la clase, es decir un objeto array, con la particularidad de que en este caso, el número de elementos del array será realmente el que establezcamos al llamar a este método.

Ejemplo:

Sub Main()

' declarar un array del modo habitual:

' este array tiene cuatro elementos,

' desde el índice 0 al 3

Dim sEstaciones(3) As String

sEstaciones(0) = "Primavera"

sEstaciones(1) = "Verano"

sEstaciones(2) = "Otoño"

sEstaciones(3) = "Invierno"

Console.WriteLine("Array sEstaciones")

MostrarArray(sEstaciones)

' crear un array instanciándolo

' con el método CreateInstance()

' de la clase Array

Dim sColores As Array

' este array tendrá tres elementos reales

' que van desde el índice 0 hasta el 2

sColores = Array.CreateInstance(GetType(String), 3)

sColores(0) = "Azul"

sColores(1) = "Rojo"

sColores(2) = "Verde"

Console.WriteLine("Array sColores")

MostrarArray(sColores)

Console.ReadLine()

End Sub

Private Sub MostrarArray(ByVal sMiLista() As String)

' muestra el array pasado como parámetro

Dim iContador As Integer

For iContador = 0 To sMiLista.Length - 1

Console.WriteLine("Elemento: {0} - Valor: {1}", _

iContador, sMiLista(iContador))

Next

Console.WriteLine()

End Sub



Aqui les dejo un ejemplo practico de lo que es un array. Es un ejercisio bien complejo


Hacer un algoritmo que realice la multiplicación entre matrices. En la multiplicación entre matrices el número de columnas de la primera matriz operando debe ser igual al número de filas de la segunda matriz operando, de lo contrario no está definida esta operación y en la matriz resultante el número de filas es igual al número de filas de la primera matriz y el número de columnas es igual al número de columnas de la segunda matriz. En el algoritmo valide la anterior condición.

link de descarga:

http://hotfile.com/dl/53914777/6cacad4/ARRAYS.rar.html

Necesitas:

visual studio 2005 o 2008
Tu dedicacion

Mucha suerte en tu estudio